[VHD] 부트 시점에 VHD 자동 마운트 처리 2 - 스크립트 버전

스크립트 방식으로 마운트 및 해제 조정하기

[이전 게시글] 에서 diskpart 를 이용한 작업 스케줄러 처리로 부트 시점에 자동 마운트 처리를 정리 했었다.

막상 실제 사용하는데 몇 가지 불만 사항이 생겨서 스크립트를 사용하는 방식으로 변경해 본다.

• 여러 개의 VHD 를 마운트 시킬 경우에 Task 를 여러 개 등록하는 문제 (한번에 여러 개 처리하는 방법을 못 찾음. ㅠㅠ)
• 특정 사용자인 경우만 처리하는 경우 (작업 스케줄러로도 처리는 가능하지만 두가지 방식 혼용이 싫음)
• 쉽게 추가/변경해서 재 시작 없이도 처리하고 싶음.
• 그냥 작업 스케줄러가 귀찮음.

위의 같은 이유로 아래와 같이 스크립트 처리를 추가했다. 기본은 diskpart를 이용하는 방식이다.

윈도우에서 스크립트를 처리할 때는 항상 관리자 권한 여부가 상당히 껄끄럽다. 이런 저런 방법들도 많다. 대략적으로는 아마 아래와 같은 형식들이 될 듯 하다.

• 레지스트리를 조정해서 항상 Cmd.exe 가 관리자 권한으로 실행되도록 한다.
• UAC 조정 또는 로그인 사용자를 관리자인 것으로 처리한다.
• 사용자를 Administrator 로만 사용한다.
• …

그런데 이런 저런 시스템 설정을 하기는 싫고 순수하게 스크립트에서만 이를 해결할 수는 없을까?

실행되는 스크립트를 관리자 모드인 것으로 처리하기

이런 저런 자료를 검토하고 나름대로 관리자 모드로 실행 부분을 생각해 보니 의외로 쉽게 할 수 있는 방법이 있다. 그것도 시스템을 건들이지 않고 스크립트 만으로 조정해서 가능하다.

@echo 관리자 권한 검증 >%windir%\admin.confirm

위의 명령은 %windir% (보통 C:\Windows) 경로에 “관리자 권한 검증” 이란 문자열을 출력해서 admin.confirm 이라는 파일을 생성하는 것이다. 당연히 관리자 권한이 없으면 액세스가 거부되었습니다. 라는 오류 메시지를 보게 된다.

이를 이용해서 아래와 같이 관리자 권한을 탈취(?)하는 코드를 생성하면 된다.

@echo 관리자 권한 검증 >%windir%\admin.confirm || @(
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\admin.vbs"
echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> %temp%\admin.vbs"
wscript.exe "%temp%\admin.vbs" & del "%temp%\admin.vbs" & exit
)

위의 명령은 관리자 권한이 없는 경우에 %temp% (보통 C:\Users\\appdata\local\temp) 에 admin.vbs 라는 파일을 만들고 아래와 같이 UAC 객체를 얻어서 실행하는 명령을 구성해서 wscript.exe 로 관리자 권한으로 실행하도록 하는 것이다.

Set UAC = CreateObject("Shell.Application")
UAC.ShellExecute "cmd_test", "", "", "runas", 1

따라서 관리자 권한을 탈취(?)하고 다시 실행되는 경우에 테스트를 위해서 만들었던 파일들을 삭제하고 나머지를 계속 수행하면 된다.

아래는 실제 작업을 진행한 코드를 보여주는 것이다. (multi_vhd_mount.bat)

@echo off

@title VHD Mount.
@setlocal enabledelayedexpansion

@echo 관리자 권한 확인용 >%windir%\admin.confirm || @(
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\admin.vbs"
echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> %temp%\admin.vbs"
wscript.exe "%temp%\admin.vbs" & del "%temp%\admin.vbs" & exit
)
@del %windir%\admin.confirm

set list=D:"C:\VMs\Workspace.vhd" E:"S:\VMs\Tools.vhd"

echo Start mounting.

for %%y in (%list%) do (
rem  echo Loop's Data: %%y
  for /F "tokens=1,* delims=: usebackq" %%a in ('%%y') do (
rem  echo Checking for file %%b to assign letter %%a:
    call %~dp0\mount_vhd %%b %%a
  )
)

echo Mounting complete.

@endlocal

• list: “Leter:VHDPath” 포맷으로 여러 개를 지정하면 처리 함.
• for %%y in (%list%) do: list 에 설정된 값 (’ ’ 값으로 분리됨 예제는 2개) 을 하나씩 %%y 변수로 할당한 루프 처리
• for /F “token=1,* delims=: usebackq” %%a in (‘%%y’) do: %%y 값을 문자열 처리하는 double quote(“) 를 제거 (usebackq 옵션) 하고 분리 문자로 “:” 사용해서 분리 (delims=:) 한 결과들 중에서 첫번째와 나머지 (token=1,*) 인 두개로 반환반환하기 때문에 %%a 는 첫 번째 결과가 %%b는 선언하지 않아도 나머지가 배정된다.

당연한 말이지만 위의 call mount_vhd %%b %%a 를 call unmount_vhd %%b 로 하면 해제 처리 가능하다.

이제 관리자 권한을 탈취해서 실행되는 스크립트를 만들었으니 내부에서 호출되는 스크립트들을 확인해 보도록 하자.

마운트 스크립트 (mount_vhd.cmd)

아래 스크립트는 VHD 를 diskpart 명령을 사용해서 처리하는 스크립트다. 중간 중간에 테스트를 위해 사용한 echo 명령은 제거해도 된다. 물론 diskpart 스크립트 파일 생성을 위한 부분은 남겨둬야 한다.

@echo off

if {%1}=={} (
    echo Usage: %~nx0 [vhd full path] [letter]
    exit /b 1
)
set vhdPath=%~dpnx1
set driveLetter=%2

if {%driveLetter%}=={} (
    echo Mounting %vhdPath%
) else (
    echo Mounting %vhdPath% to %driveLetter%:
)

REM
REM create dispart script
REM
set diskPartScript=%~nx0.diskpart
echo sel vdisk file="%vhdPath%">%diskPartScript%
echo attach vdisk>>%diskPartScript%

REM assign the drive letter if requested
if not {%driveLetter%}=={} (
    echo select partition 1 >>%diskPartScript%
    echo assign letter=%driveLetter%>>%diskPartScript%
)

REM Show script
echo.
echo Running diskpart script:
type %diskPartScript%

REM
REM diskpart
REM
diskpart /s %diskPartScript%
del /q %diskPartScript%

echo Done!

• %1: 첫 번째 파라미터, 없으면 사용방법 출력
• %2: 두 번째 파라미터
• ~nx0: 실행하고 있는 cmd 파일 명
• %~dpnx1: 첫 번째 파라미터의 경로를 포함한 값
• %..%: set 으로 설정된 것 포함 환경변수 값

해제 스크립트 (unmount_vhd.cmd)

아래 스크립트는 마운트해서 사용한 VHD 를 연결 해제하는 스크립트다.

@echo off

if {%1}=={} (
    echo Usage: %~nx0 [vhd full path]
    exit /b 1
)
set vhdPath=%~dpnx1

echo Unmounting %vhdPath%

REM
REM create dispart script
REM

set diskPartScript=%~nx0.diskpart
echo sel vdisk file="%vhdPath%">%diskPartScript%
echo detach vdisk>>%diskPartScript%

REM
REM diskpart
REM

diskpart /s %diskPartScript%
del /q %diskPartScript%

echo Done!

자동 실행 등록

수동으로 실행을 해도 되지만, 작업 스케줄러를 이용해도 되고, 아래에서 확인해 볼 것처럼 시작 프로그램으로 등록해 놓고 사용해도 된다.

시작 프로그램 폴더 사용

• 개별 사용자: %APPDATA%\Microsoft\Windows\Start Menu\Programs\Startup
• 모든 사용자: %ProgramData%\Microsoft\Windows\Start Menu\Programs\Startup

위의 폴더 중에서 원하는 위치에 작성한 스크립트를 복사해 놓으면 된다. (단, 내부에서 사용한 다른 호출 스크립트 경로를 조정해 줘야 한다)

레지스트리 기준 시작 프로그램 등록

레지스트리 편집기 (regedit)를 열고 아래의 키 들 중에 원하는 위치로 이동한다.

• 개별 사용자: HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run
• 모든 사용자: HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Run

해당 키 하위로 새로운 문자열 키 를 생성하고 이름은 원하는데로 설정하고, 데이터는 실행할 배치 파일을 전체 경로를 설정하면 된다.

Conclustion

Notes

배치는 잠시지만 명령 창이 나타났다 사라진다. 차라리 길게 보이면 그럭저럭 넘길텐데, 후다닥 지나가면 뭔가 오류가 발생한 느낌이 나기 때문에 심하게 싫다.

이런 경우라면 아래와 같이 VBS 처리를 해주면 보이지 않게 된다. 아래 코드에서 <실행할 Command 파일> 를 위에서 만든 스크립트 파일 전체 경로로 바꿔야 한다.

Set WinScriptHost = CreateObject( "WScript.shell" )
WinScriptHost.Run Chr(34) & <실행할 Command 파일> & Chr(34), 0
Set WinScriptHost = Nothing

위와 같이 처리를 해서 이 VBS 파일을 위에 자동 실행 등록으로 처리하면 정신적으로 위로(?)가 된다.

역시 뭔가 자꾸 바꾸고 테스트하는 것은 스크립트를 활용하는 것이 좋다. 물론 한번 설정하고 안 바꿀 거라면 작업 스케줄러도 나쁘지는 않다. 단, 적응이 안되니 그냥 뭔가 귀찮고 싫을 뿐이다.

배치 파일, VHD 관련 정보는 고수님들이 친절하게 설명한 글이 무수하게 많으니 꼭 찾아서 읽어보는 것이 좋다.

---

Written by Morris (ccambo@gmail.com - MSFL)